#!/usr/bin/awk -f

BEGIN {
	NOREDO = 0;
	FILEBYFILE = 0;
	DOIT = 0;
	SPFILE = 0;

	DEST = "/pkg/prdgenl/backup/prdgenl/";
	LOGFILE = "/tmp/awkback"

	CONNECT = "connect sys/xxx";
	QUIET = "set pages 0 lin 32767 feedback off verify off heading off";
	SQLPLUS = ENVIRON["ORACLE_HOME"] "/bin/sqlplus -silent /nolog";
	INITORA = ENVIRON["ORACLE_HOME"] "/dbs/init"ENVIRON["ORACLE_SID"]".ora";
	UDUMP = ENVIRON["ORACLE_HOME"] "/udump";

# (Most) OS-Specific settings
	CP = "cp";
	MV = "mv";
	LOG = " >> " LOGFILE ".log 2>&1";
	COMPRESS = "bzip2 -9q";
	CMDINIT = SQLPLUS "<<EOF\n" CONNECT "\n" QUIET "\n";


	for(i = 1; i < ARGC; i++)
	{
		if(ARGV[i] == "HELP") Usage();
		if(ARGV[i] == "NOREDO") NOREDO = 1;
		if(ARGV[i] == "FILEBYFILE") FILEBYFILE = 1;
		if(ARGV[i] == "DOIT") DOIT = 1;
		if(ARGV[i] == "SPFILE") SPFILE = 1;
		if(substr(ARGV[i],1,5) == "DEST=") DEST = xeq(ARGV[i]);
		if(substr(ARGV[i],1,8) == "CONNECT=") CONNECT = xeq(ARGV[i]);
		if(substr(ARGV[i],1,6) == "QUIET=") QUIET = xeq(ARGV[i]);
		if(substr(ARGV[i],1,8) == "SQLPLUS=") SQLPLUS = xeq(ARGV[i]);
		if(substr(ARGV[i],1,8) == "INITORA=") INITORA = xeq(ARGV[i]);
		if(substr(ARGV[i],1,6) == "UDUMP=") UDUMP = xeq(ARGV[i]);
		if(substr(ARGV[i],1,8) == "CP=") CP = xeq(ARGV[i]);
		if(substr(ARGV[i],1,8) == "MV=") MV = xeq(ARGV[i]);
		if(substr(ARGV[i],1,9) == "COMPRESS=") COMPRESS = xeq(ARGV[i]);
		if(substr(ARGV[i],1,9) == "LGMNRDCT=") LGMNRDCT = xeq(ARGV[i]);
	}


	LATEST_TRACE = "cd " UDUMP \
		";cp $(ls -t $(fgrep -l 'CREATE CONTROLFILE' *.trc)|head -1) " \
		DEST;


	script = "set echo on define off\nspool " LOGFILE "\n";

	pfile_backup();

	if(LGMNRDCT) logminerdict(LGMNRDCT);

	bin_controlfile_backup();

	trace_controlfile_backup();

	build_df_array();

	if(FILEBYFILE)
		file_by_file_backup();
	else
		whole_tablespace_backup();

	if(!NOREDO) hot_copy_redo();

	script = script "quit\n";

	if(DOIT)
	{
		cmd = CMDINIT script "\nEOF\n";
		while(cmd | getline)
			print;
	}
	else
		print script;
}


function xeq(x)
{
	return substr(x, 1 + index(x, "="));
}


function pfile_backup()
{
	if(SPFILE)
		script = script "CREATE PFILE='" DEST "init" \
			ENVIRON["ORACLE_SID"] ".ora' FROM SPFILE;\n"
	else
		script = script "!" CP " " INITORA " " DEST LOG "\n"
}


function logminerdict(dpath)
{
	dname = basename(dpath)
	ddir  = dirname(dpath)

	script = script "begin\nsys.dbms_logmnr_d.build('" dname "', '" \
		ddir "');\nend;\n/\n!" CP " " dpath " " DEST "\n" \
		"!" COMPRESS " " DEST dname LOG "\n";
}



function bin_controlfile_backup()
{
	script = script "alter database backup controlfile to '" DEST \
		"CONTROL.BAK';\n";

	script = script "!" COMPRESS " " DEST "CONTROL.BAK" LOG "\n";
}


function trace_controlfile_backup()
{
	script = script "alter database backup controlfile to trace;\n";
	script = script "!" LATEST_TRACE LOG "\n";
}


function build_df_array(	cmd)
{
	cmd = CMDINIT \
	"select '+'||file_name,tablespace_name from dba_data_files;\nEOF\n";

	while(cmd | getline)
		if(substr($0, 1, 1) == "+" ) file[substr($1, 2)] = $2;

	close(cmd);
}


function whole_tablespace_backup(	x, y)
{
	for(x in file) tablespace[file[x]] = 1;

	for(x in tablespace)
	{
		script = script "alter tablespace " x " begin backup;\n";
		for(y in file)
			if(file[y] == x)
				script = script "!" CP " " y " " DEST LOG "\n";
		script = script "alter tablespace " x " end backup;\n";
		for(y in file)
			if(file[y] == x)
				script = script "!" COMPRESS " " DEST \
					basename(y) LOG "\n";
	}
}


function file_by_file_backup(		x)
{
	for(x in file)
	{
		script = script "alter tablespace " file[x] " begin backup;\n";
		script = script "!" CP " " x " " DEST LOG "\n";
		script = script "alter tablespace " file[x] " end backup;\n";
		script = script "!" COMPRESS " " DEST basename(x) LOG "\n";
	}
}


function hot_copy_redo(		x, cmd, logs)
{
	cmd = CMDINIT \
		"SELECT '+'|| RTRIM(x.member) FROM v\\\$logfile x " \
		"WHERE x.member IN ( SELECT member FROM v\\\$logfile WHERE " \
		"group# = x.group# AND rownum < 2 );\nEOF\n";

	while(cmd | getline)
		if(substr($0, 1, 1) == "+")
			logs[substr($1, 2)] = 1;

	script = script "!" CP " ";

	for(x in logs)
		script = script x " ";

	script = script DEST LOG "\n";

	for(x in logs)
		script = script "!" MV " " DEST basename(x) " " \
			DEST "do-not-use-" basename(x) LOG "\n" \
			"!"COMPRESS " " DEST "do-not-use-" basename(x) LOG "\n";
}


function basename(x)
{
	gsub(/.*\//, "", x);
	gsub(/.*\\/, "", x);
	return x;
}


function dirname(x)
{
	gsub(/[\\\/][^\\\/]*$/, "", x);
	return x;
}


function p(x)
{
	print x;
}


function Usage()
{
	p("\nawkback - Oracle7-style hot backup of an online database.\n");
	p("Options:");
	p("\tNOREDO - Do not copy online redo (not Oracle-supported).");
	p("\tFILEBYFILE - Don't copy a whole tablespace at once (disk space).");
	p("\tDOIT - Don't just print out the script, run it.");
	p("\tSPFILE - Ignore any init.ora, dump binary spfile.");
	p("\tINITORA - Path to init.ora (can include addl files).");
	p("\tDEST - Destination directory; include trailing slash.");
	p("\tCONNECT= - Oracle account logon (connect internal).");
	p("\tSQLPLUS= - Path to sqlplus, with command line args.");
	p("\tQUIET= - sqlplus directive for terse output.");
	p("\tBDUMP= - Directory to find controlfile trace.");
	p("\tLGMNRDCT= - Create dictionary in utl_file_dir, then backup.");
	p("\tCP - OS copy command.");
	p("\tMV - OS move command.");
	p("\nExample:");
	p("\tORACLE_SID=orcl ORACLE_HOME=/oracle awkback SPFILE DOIT");
	exit;
}